模块 ngx_http_perl_module

已知问题 示例配置 指令      perl      perl_modules      perl_require      perl_set 从 SSI 调用 Perl $r 请求对象方法

ngx_http_perl_module 模块用于在 Perl 中实现位置和变量处理程序，并将 Perl 调用插入到 SSI 中。

此模块默认情况下未构建，应使用 --with-http_perl_module 配置参数启用它。

此模块需要 Perl 5.6.1 或更高版本。C 编译器应与用于构建 Perl 的编译器兼容。

已知问题

该模块是实验性的，适用买者自负原则。

为了让 Perl 在重新配置期间重新编译修改的模块，应使用 -Dusemultiplicity=yes 或 -Dusethreads=yes 参数构建它。此外，为了让 Perl 在运行时减少内存泄漏，应使用 -Dusemymalloc=no 参数构建它。要检查已构建 Perl 中的这些参数的值（首选值在示例中指定），请运行

$ perl -V:usemultiplicity -V:usemymalloc
usemultiplicity='define';
usemymalloc='n';

请注意，在使用新的 -Dusemultiplicity=yes 或 -Dusethreads=yes 参数重新构建 Perl 后，所有二进制 Perl 模块也必须重新构建 — 它们将停止与新的 Perl 一起工作。

主进程和工作进程有可能在每次重新配置后都会增大。如果主进程增长到不可接受的大小，则可以应用 实时升级 过程，而无需更改可执行文件。

当 Perl 模块执行长时间运行的操作（例如解析域名、连接到另一台服务器或查询数据库）时，分配给当前工作进程的其他请求将不会被处理。因此，建议仅执行执行时间可预测且较短的操作，例如访问本地文件系统。

示例配置

http {

    perl_modules perl/lib;
    perl_require hello.pm;

    perl_set $msie6 '

        sub {
            my $r = shift;
            my $ua = $r->header_in("User-Agent");

            return "" if $ua =~ /Opera/;
            return "1" if $ua =~ / MSIE [6-9]\.\d+/;
            return "";
        }

    ';

    server {
        location / {
            perl hello::handler;
        }
    }

perl/lib/hello.pm 模块

package hello;

use nginx;

sub handler {
    my $r = shift;

    $r->send_http_header("text/html");
    return OK if $r->header_only;

    $r->print("hello!\n<br/>");

    if (-f $r->filename or -d _) {
        $r->print($r->uri, " exists!\n");
    }

    return OK;
}

1;
__END__

指令

为给定位置设置 Perl 处理程序。

设置 Perl 模块的附加路径。

定义将在每次重新配置期间加载的模块的名称。可以存在多个 perl_require 指令。

为指定的变量安装 Perl 处理程序。

从 SSI 调用 Perl

调用 Perl 的 SSI 命令具有以下格式

<!--# perl sub="module::function" arg="parameter1" arg="parameter2" ...
-->

$r 请求对象方法

$r->args

返回请求参数。

$r->filename

返回与请求 URI 相对应的文件名。

$r->has_request_body(handler)

如果请求中没有正文，则返回 0。如果存在正文，则为请求设置指定的处理程序并返回 1。在读取请求正文后，nginx 将调用指定的处理程序。请注意，应按引用传递处理程序函数。示例

package hello;

use nginx;

sub handler {
    my $r = shift;

    if ($r->request_method ne "POST") {
        return DECLINED;
    }

    if ($r->has_request_body(\&post)) {
        return OK;
    }

    return HTTP_BAD_REQUEST;
}

sub post {
    my $r = shift;

    $r->send_http_header;

    $r->print("request_body: \"", $r->request_body, "\"<br/>");
    $r->print("request_body_file: \"", $r->request_body_file, "\"<br/>\n");

    return OK;
}

1;

__END__

$r->allow_ranges

在发送响应时启用使用字节范围。

$r->discard_request_body

指示 nginx 丢弃请求正文。

$r->header_in(field)

返回指定的客户端请求标头字段的值。

$r->header_only

确定应将整个响应还是仅其标头发送给客户端。

$r->header_out(field, value)

为指定的响应标头字段设置值。

$r->internal_redirect(uri)

对指定的 uri 执行内部重定向。实际重定向在 Perl 处理程序执行完成后发生。

从 1.17.2 版本开始，该方法接受转义的 URI，并支持重定向到命名位置。

$r->log_error(errno, message)

将指定的 message 写入 error_log。如果 errno 非零，则错误代码及其描述将附加到消息中。

$r->print(text, ...)

将数据传递给客户端。

$r->request_body

如果客户端请求正文尚未写入临时文件，则返回该正文。为了确保客户端请求正文位于内存中，其大小应受 client_max_body_size 限制，并且应使用 client_body_buffer_size 设置足够的缓冲区大小。

$r->request_body_file

返回包含客户端请求正文的文件名。处理后，应删除该文件。要始终将请求正文写入文件，应启用 client_body_in_file_only。

$r->request_method

返回客户端请求 HTTP 方法。

$r->remote_addr

返回客户端 IP 地址。

$r->flush

立即向客户端发送数据。

$r->sendfile(name[, offset[, length]])

向客户端发送指定的文件内容。可选参数指定要传输的数据的初始偏移量和长度。实际数据传输在 Perl 处理程序完成后发生。

$r->send_http_header([type])

向客户端发送响应头。可选的 type 参数设置“Content-Type”响应头字段的值。如果该值为一个空字符串，则不会发送“Content-Type”头字段。

$r->status(code)

设置响应代码。

$r->sleep(milliseconds, handler)

设置指定处理程序并停止请求处理指定时间。同时，nginx 继续处理其他请求。在指定时间过去后，nginx 将调用已安装的处理程序。请注意，处理程序函数应通过引用传递。为了在处理程序之间传递数据，应使用 $r->variable()。示例

package hello;

use nginx;

sub handler {
    my $r = shift;

    $r->discard_request_body;
    $r->variable("var", "OK");
    $r->sleep(1000, \&next);

    return OK;
}

sub next {
    my $r = shift;

    $r->send_http_header;
    $r->print($r->variable("var"));

    return OK;
}

1;

__END__

$r->unescape(text)

解码以“%XX”形式编码的文本。

$r->uri

返回请求 URI。

$r->variable(name[, value])

返回或设置指定变量的值。变量是每个请求的局部变量。